How am I supposed to use COGINIT in SPIN2 to control multiple cogs in parallel?

Comments

• Electrodude Posts: 1,682

  2025-10-13 21:29

  Please format code inside ``` codeblocks so we can easily see indentation.

  You have a couple of problems. main runs in cog 0, but the first thing it does is restart itself with your blink function, so nothing else in main runs. Perhaps make main only start cogs 1-7 and then call blink itself.

  Do you need to allocate cog numbers yourself when you can make coginit just use the next free one? Sorry, I'm on my phone and forget the constant you need to pass coginit to make it do this, but it's in the documentation.

  You're going to have a bad time trying to flash LEDs on pins 56-63, since they're already used for programming. The biggest symptom you'll probably see is that it interferes with debug output.
• Wuerfel_21 Posts: 5,658

  2025-10-13 22:08

  For launching Spin2 cogs, you should be using cogspin (infact, I don't think @blink with blink being a PUB/PRI function is even valid syntax??). coginit is for launching ASM code only (this changed from Spin1!)
• JonnyMac Posts: 9,474

  2025-10-13 22:14 edited 2025-10-13 22:57

  I am new to Spin2 and am having enormous difficulty.

  Then why are you starting with something so obtuse? Learn the basics first, and if you want to prove to yourself that you can run the same code in multiple cogs, do it with two cogs to start with, and do make your code obvious. I copied your code from the forums and it doesn't run -- and it's not worth taking the time to fix. My version of a multi-cog blinker is easier to understand and more flexible than what you're attempting.

  When in doubt, keep it simple.

  var { globals }
  
    long  cid0                                                    ' cog for first blinker
    long  stack0[32]                                              ' stack for first blinker
  
    long  cid1                                                    ' cog for second blinker
    long  stack1[32]                                              ' stack for second blinker
  
  
  pub main() | i, byte cogsused
  
    cid0 := cogspin(newcog, blinker(LED1 , 50,  50), @stack0)     ' fast blink on P56
    cid1 := cogspin(newcog, blinker(LED2, 700, 300), @stack1)     ' slow blink on P57
  
    repeat i from 0 to 7                                          ' scan all cogs
      cogsused.[i] := cogchk(i)                                   '  mark if in use
  
    debug("Blinkers using cogs ", udec_(cid0), " and ", udec_(cid1))
    debug("Cogs in use: ", ubin_byte_(cogsused))
  
    repeat
    ' forever
  
  
  pri blinker(pin, mson, msoff)                                   ' launch with cogspin
  
    repeat
      pinhigh(pin)
      waitms(mson)
      pinlow(pin)
      waitms(msoff)
  
  

  spin2

  spin2

  jm_dual_blinker.spin2

  4K

  jm_dual_blinker.spin2 4.1K
• JonnyMac Posts: 9,474

  2025-10-13 22:35 edited 2025-10-14 01:02

  Before deleting the file I looked one more time

  • You need to use cogspin to launch Spin methods into their own cog (new interpreter); coginit is for PASM cogs
  • Better to use newcog instead of attempting to crowbar code into a specific cog (unless it's a deliberate replacement issue)
  • Your code wants to trample on cog0 which is loading everything else
  • Your code wants to use P62 and P63 which are used by the DEBUG serial routines

  This works

  PUB main() | i
  
    repeat i from 1 to 5
      cogida[i] := cogspin(i, blink(), @stack[i*32])
      if cogida[i] < 0
        debug("cogspin failed for cog", i, " : ", cogida[i], "\n")
      waitms(200)
  
    repeat
      waitms(1000)
  
  PUB blink() | mypin
  
    mypin := 56 + cogid() 'LEDs 57 à 61
    repeat
      pintoggle(mypin)
      waitms(300)
  

  Note that pintoggle sets the direction bit for the pin so you don't need to do it manually. With Spin2's pin control commands there is almost no reason to deal with the direction bits directly.
• JonnyMac Posts: 9,474

  2025-10-14 02:55

  For fun a quad version that uses cogspin and coginit.

  spin2

  spin2

  jm_quad_blinker.spin2

  5K

  jm_quad_blinker.spin2 5.1K