fl

{
      
PropForth 5.5
2023/08/30 20:42:17

8x8Matrix-module on Max7219
   b7....b0 b7....b0 b7....b0 b7....b0
   -----------------------------------
  | Digit1 | Digit1 | Digit1 | Digit1 |
  | Digit2 | Digit2 | Digit2 | Digit2 |
  | Digit3 | Digit3 | Digit3 | Digit3 |- <----5V
  | Digit4 | Digit4 | Digit4 | Digit4 |-      GND
  | Digit5 | Digit5 | Digit5 | Digit5 |-      DIN
  | Digit6 | Digit6 | Digit6 | Digit6 |-      CS
  | Digit7 | Digit7 | Digit7 | Digit7 |-      CLK
  | Digit8 | Digit8 | Digit8 | Digit8 |
   -----------------------------------

}

\ =========================================================================== 
\ Constants 
\ =========================================================================== 
0 wconstant din
1 wconstant cs
2 wconstant clk
\ register
h900 constant decode
hA00 constant intensity
hB00 constant scan
hC00 constant shutdown
hF00 constant test

\   character h31 "1"                        
\   b7 b6 b5 b4 b3 b2 b1 b0  address
\                            Low
\    1                        |
\    1                 1      |
\    1  1  1  1  1  1  1  1   |
\    1  1  1  1  1  1  1  1   |
\    1                        |
\    1                        V
\                            High
wvariable Font -2 allot
h00 c, h00 c, h00 c, h00 c, h00 c, h00 c, h00 c, h00 c,
h00 c, h06 c, h5F c, h5F c, h06 c, h00 c, h00 c, h00 c,
h00 c, h03 c, h07 c, h00 c, h07 c, h03 c, h00 c, h00 c,
h14 c, h7F c, h7F c, h14 c, h7F c, h7F c, h14 c, h00 c,
h24 c, h2E c, h2A c, h6B c, h6B c, h3A c, h12 c, h00 c,
h46 c, h66 c, h30 c, h18 c, h0C c, h66 c, h62 c, h00 c,
h30 c, h7A c, h4F c, h5D c, h37 c, h7A c, h48 c, h00 c,
h00 c, h04 c, h07 c, h03 c, h00 c, h00 c, h00 c, h00 c,
h00 c, h1C c, h3E c, h63 c, h41 c, h00 c, h00 c, h00 c,
h00 c, h41 c, h63 c, h3E c, h1C c, h00 c, h00 c, h00 c,
h08 c, h2A c, h3E c, h1C c, h1C c, h3E c, h2A c, h08 c,
h08 c, h08 c, h3E c, h3E c, h08 c, h08 c, h00 c, h00 c,
h00 c, h80 c, hE0 c, h60 c, h00 c, h00 c, h00 c, h00 c,
h08 c, h08 c, h08 c, h08 c, h08 c, h08 c, h00 c, h00 c,
h00 c, h00 c, h60 c, h60 c, h00 c, h00 c, h00 c, h00 c,
h60 c, h30 c, h18 c, h0C c, h06 c, h03 c, h01 c, h00 c,
h3E c, h7F c, h41 c, h49 c, h41 c, h7F c, h3E c, h00 c,
h40 c, h42 c, h7F c, h7F c, h40 c, h40 c, h00 c, h00 c,
h62 c, h73 c, h59 c, h49 c, h6F c, h66 c, h00 c, h00 c,
h22 c, h63 c, h49 c, h49 c, h7F c, h36 c, h00 c, h00 c,
h18 c, h1C c, h16 c, h53 c, h7F c, h7F c, h50 c, h00 c,
h27 c, h67 c, h45 c, h45 c, h7D c, h39 c, h00 c, h00 c,
h3C c, h7E c, h4B c, h49 c, h79 c, h30 c, h00 c, h00 c,
h03 c, h03 c, h71 c, h79 c, h0F c, h07 c, h00 c, h00 c,
h36 c, h7F c, h49 c, h49 c, h7F c, h36 c, h00 c, h00 c,
h06 c, h4F c, h49 c, h69 c, h3F c, h1E c, h00 c, h00 c,
h00 c, h00 c, h66 c, h66 c, h00 c, h00 c, h00 c, h00 c,
h00 c, h80 c, hE6 c, h66 c, h00 c, h00 c, h00 c, h00 c,
h08 c, h1C c, h36 c, h63 c, h41 c, h00 c, h00 c, h00 c,
h24 c, h24 c, h24 c, h24 c, h24 c, h24 c, h00 c, h00 c,
h00 c, h41 c, h63 c, h36 c, h1C c, h08 c, h00 c, h00 c,
h02 c, h03 c, h51 c, h59 c, h0F c, h06 c, h00 c, h00 c,
h3E c, h7F c, h41 c, h5D c, h5D c, h1F c, h0E c, h00 c,
h7C c, h7E c, h13 c, h13 c, h7E c, h7C c, h00 c, h00 c,
h41 c, h7F c, h7F c, h49 c, h49 c, h7F c, h36 c, h00 c,
h1C c, h3E c, h63 c, h41 c, h41 c, h63 c, h22 c, h00 c,
h41 c, h7F c, h7F c, h41 c, h63 c, h3E c, h1C c, h00 c,
h41 c, h7F c, h7F c, h49 c, h5D c, h41 c, h63 c, h00 c,
h41 c, h7F c, h7F c, h49 c, h1D c, h01 c, h03 c, h00 c,
h1C c, h3E c, h63 c, h41 c, h51 c, h73 c, h72 c, h00 c,
h7F c, h7F c, h08 c, h08 c, h7F c, h7F c, h00 c, h00 c,
h00 c, h41 c, h7F c, h7F c, h41 c, h00 c, h00 c, h00 c,
h30 c, h70 c, h40 c, h41 c, h7F c, h3F c, h01 c, h00 c,
h41 c, h7F c, h7F c, h08 c, h1C c, h77 c, h63 c, h00 c,
h41 c, h7F c, h7F c, h41 c, h40 c, h60 c, h70 c, h00 c,
h7F c, h7F c, h0E c, h1C c, h0E c, h7F c, h7F c, h00 c,
h7F c, h7F c, h06 c, h0C c, h18 c, h7F c, h7F c, h00 c,
h1C c, h3E c, h63 c, h41 c, h63 c, h3E c, h1C c, h00 c,
h41 c, h7F c, h7F c, h49 c, h09 c, h0F c, h06 c, h00 c,
h1E c, h3F c, h21 c, h71 c, h7F c, h5E c, h00 c, h00 c,
h41 c, h7F c, h7F c, h09 c, h19 c, h7F c, h66 c, h00 c,
h26 c, h6F c, h49 c, h49 c, h7B c, h32 c, h00 c, h00 c,
h03 c, h41 c, h7F c, h7F c, h41 c, h03 c, h00 c, h00 c,
h3F c, h7F c, h40 c, h40 c, h7F c, h3F c, h00 c, h00 c,
h1F c, h3F c, h60 c, h60 c, h3F c, h1F c, h00 c, h00 c,
h7F c, h7F c, h30 c, h18 c, h30 c, h7F c, h7F c, h00 c,
h61 c, h73 c, h1E c, h0C c, h1E c, h73 c, h61 c, h00 c,
h07 c, h4F c, h78 c, h78 c, h4F c, h07 c, h00 c, h00 c,
h47 c, h63 c, h71 c, h59 c, h4D c, h67 c, h73 c, h00 c,
h00 c, h7F c, h7F c, h41 c, h41 c, h00 c, h00 c, h00 c,
h01 c, h03 c, h06 c, h0C c, h18 c, h30 c, h60 c, h00 c,
h00 c, h41 c, h41 c, h7F c, h7F c, h00 c, h00 c, h00 c,
h08 c, h0C c, h06 c, h03 c, h06 c, h0C c, h08 c, h00 c,
h80 c, h80 c, h80 c, h80 c, h80 c, h80 c, h80 c, h80 c,
h00 c, h00 c, h01 c, h03 c, h06 c, h04 c, h00 c, h00 c,
h20 c, h74 c, h54 c, h54 c, h3C c, h78 c, h40 c, h00 c,
h41 c, h7F c, h3F c, h48 c, h48 c, h78 c, h30 c, h00 c,
h38 c, h7C c, h44 c, h44 c, h6C c, h28 c, h00 c, h00 c,
h30 c, h78 c, h48 c, h49 c, h3F c, h7F c, h40 c, h00 c,
h38 c, h7C c, h54 c, h54 c, h5C c, h18 c, h00 c, h00 c,
h48 c, h7E c, h7F c, h49 c, h03 c, h02 c, h00 c, h00 c,
h98 c, hBC c, hA4 c, hA4 c, hF8 c, h7C c, h04 c, h00 c,
h41 c, h7F c, h7F c, h08 c, h04 c, h7C c, h78 c, h00 c,
h00 c, h44 c, h7D c, h7D c, h40 c, h00 c, h00 c, h00 c,
h60 c, hE0 c, h80 c, h80 c, hFD c, h7D c, h00 c, h00 c,
h41 c, h7F c, h7F c, h10 c, h38 c, h6C c, h44 c, h00 c,
h00 c, h41 c, h7F c, h7F c, h40 c, h00 c, h00 c, h00 c,
h7C c, h7C c, h08 c, h38 c, h0C c, h7C c, h78 c, h00 c,
h7C c, h7C c, h04 c, h04 c, h7C c, h78 c, h00 c, h00 c,
h38 c, h7C c, h44 c, h44 c, h7C c, h38 c, h00 c, h00 c,
h84 c, hFC c, hF8 c, hA4 c, h24 c, h3C c, h18 c, h00 c,
h18 c, h3C c, h24 c, hA4 c, hF8 c, hFC c, h84 c, h00 c,    
h44 c, h7C c, h78 c, h4C c, h04 c, h1C c, h18 c, h00 c,
h48 c, h5C c, h54 c, h54 c, h74 c, h24 c, h00 c, h00 c,
h00 c, h04 c, h3E c, h7F c, h44 c, h24 c, h00 c, h00 c,
h3C c, h7C c, h40 c, h40 c, h3C c, h7C c, h40 c, h00 c,
h1C c, h3C c, h60 c, h60 c, h3C c, h1C c, h00 c, h00 c,
h3C c, h7C c, h60 c, h38 c, h60 c, h7C c, h3C c, h00 c,
h44 c, h6C c, h38 c, h10 c, h38 c, h6C c, h44 c, h00 c,
h9C c, hBC c, hA0 c, hA0 c, hFC c, h7C c, h00 c, h00 c,
h4C c, h64 c, h74 c, h5C c, h4C c, h64 c, h00 c, h00 c,
h08 c, h08 c, h3E c, h77 c, h41 c, h41 c, h00 c, h00 c,
h00 c, h00 c, h7F c, h7F c, h00 c, h00 c, h00 c, h00 c,
h41 c, h41 c, h77 c, h3E c, h08 c, h08 c, h00 c, h00 c,
h02 c, h03 c, h01 c, h03 c, h02 c, h03 c, h01 c, h00 c,
h4C c, h5E c, h73 c, h01 c, h73 c, h5E c, h4C c, h00 c,   \ Font + d760
h03 c, h03 c, h1C c, h3E c, h41 c, h41 c, h63 c, h22 c,   \ Font + d768

\ =========================================================================== 
\ Variables 
\ =========================================================================== 
variable buffer d28 allot

\ =========================================================================== 
\ Main 
\ =========================================================================== 

: cs_l cs pinlo ;
: cs_h cs pinhi ;
: clk_l clk pinlo ;
: clk_h clk pinhi ;
: din_l din pinlo ;
: din_h din pinhi ;


\ Shift out data with MSBfirst
\ ( n1 -- )
: shiftOut
h8000
d16 0 do
  2dup and 0=
  if din_l else din_h then
  clk_h clk_l
  1 rshift
loop
2drop
;

\ Clear 8x8matrix
\ ( -- )
: clrMatrix        
9 1 do
  cs_l
  4 0 do j 8 lshift shiftOut loop
  cs_h
loop
buffer d32 0 fill
;

\ Initialize MAX7219
\ ( -- )  
: init 
cs pinout clk pinout din pinout cs_h

cs_l decode shiftOut cs_h
cs_l intensity 1 + shiftOut cs_h
cs_l scan 7 + shiftOut cs_h
cs_l shutdown 1 + shiftOut cs_h
cs_l 0 shiftOut cs_h
cs_l 0 shiftOut cs_h
cs_l 0 shiftOut cs_h
clrMatrix
;

\ Get bit data from Font character[1byte] to buffer[Digit1[b0]..Digit7[b0]]
\ ( n1 -- ) n1:byte
: getCharBit
buffer                          \ ( byte buffer )
8 0 do
  over 1 i lshift and 
  if dup L@ 1+ over L! then
  4 + 
loop
2drop
;

\ Combine Digit address and data
\ ( n1 n2 -- ) n1:each buffer address n2:1,2,3,4,5,6,7,8
: 16bitshiftOut 8 lshift swap C@ or shiftOut ;
 
\ Send data to MAX7219
\ ( -- )
: sendData
buffer
9 1 do
  dup i 1- 4* +
  cs_l
  dup 3 + i
  16bitshiftOut
  dup 2+ i
  16bitshiftOut
  dup 1+ i
  16bitshiftOut
  i
  16bitshiftOut
  cs_h
loop
drop
;

\ Display character
\ ( n1 -- ) n1:ascii code
: dispChar
h20 - 8 * Font +

8 0 do
  dup 
  C@ getCharBit  
  sendData
  d50 delms
  buffer 8 0 do dup L@ 1 lshift over L! 4+ loop drop
  1+
loop
drop
;

\ Display string
\ ( cstr -- )   cstr:string addr
: dispStr
C@++                               \ ( c-addr+1 c1 )  c-addr+1: string's first char addr  c1:string length
dup 
if 
     bounds do i C@ dispChar loop  \ Print string 
else 
     2drop 
then 
;



\ Move shift dot from right to left on Digit1-line
\ ( -- )
: test1 
1 buffer L!
d32 0 do
  cs_l
  buffer L@ d24 rshift h100 or dup . cr shiftOut
  buffer L@ d16 rshift hFF and h100 or dup . cr shiftOut
  buffer L@ 8 rshift hFF and h100 or dup . cr shiftOut
  buffer L@ hFF and h100 or dup . cr  shiftOut
  cs_h
  buffer L@ 1 lshift dup . cr buffer L!   cr
  10 delms            
loop
;

\ Move shift vertical-line from L to R
\ ( -- )
: test2
clrMatrix
hFF getCharBit    
sendData
\ buffer 
d31 0 do 
  \ Shift 1bit buffer[Digit1...Digit8] to left
  buffer 8 0 do dup L@ 1 lshift over L! 4+ loop drop
  \ Shift each LED-line[Digit1...Digit8] of 8x8Matrix
  sendData
  d150 delms
loop     
d32 0 do 
  \ Shift 1bit buffer[Digit1...Digit8] to riht
  buffer 8 0 do dup L@ 1 rshift over L! 4+ loop drop
  \ Shift each LED-line[Digit1...Digit8] of 8x8Matrix
  sendData
  d150 delms
loop     
;

\ Display characters
\ ( -- )
: test3
clrMatrix

h20
begin
  dup
  dispChar
  1+
  d50 delms
  h80 over < if drop h20 then  
  fkey? swap drop
until
drop
;

\ Display string
\ ( -- )
: test4
clrMatrix
begin
  c" May the Forth be with you " dispStr
  fkey? swap drop
until
;