' =========================================================================
'
'   File....... PSX_Test.BS2
'   Purpose.... Test program for SX-based PSX Helper module
'   Author..... Jon Williams -- Parallax, Inc.
'   E-mail..... jwilliams@parallax.com
'   Started....
'   Updated.... 19 NOV 2005
'
'   {$STAMP BS2}
'   {$PBASIC 2.5}
'
' =========================================================================


' -----[ Program Description ]---------------------------------------------
'
' Simple test program for PlayStion Helper chip.


' -----[ Revision History ]------------------------------------------------


' -----[ I/O Definitions ]-------------------------------------------------

Sio             PIN     15


' -----[ Constants ]-------------------------------------------------------

#SELECT $STAMP
  #CASE BS2, BS2E, BS2PE
    T1200       CON     813
    T2400       CON     396
    T4800       CON     188
    T9600       CON     84
    T19K2       CON     32
    TMidi       CON     12
    T38K4       CON     6
  #CASE BS2SX, BS2P
    T1200       CON     2063
    T2400       CON     1021
    T4800       CON     500
    T9600       CON     240
    T19K2       CON     110
    TMidi       CON     60
    T38K4       CON     45
  #CASE BS2PX
    T1200       CON     3313
    T2400       CON     1646
    T4800       CON     813
    T9600       CON     396
    T19K2       CON     188
    TMidi       CON     108
    T38K4       CON     84
#ENDSELECT

SevenBit        CON     $2000
Inverted        CON     $4000
Open            CON     $8000

Baud            CON     Open + T38K4


' -----[ Variables ]-------------------------------------------------------

id              VAR     Byte(3)
type            VAR     Byte

psx             VAR     Byte                    ' psx data
psxThumb1       VAR     psx                     ' thumb buttons
psxThumb2       VAR     Byte                    ' thumb buttons
psxJoyRX        VAR     Byte                    ' r joystick - X axis
psxJoyRY        VAR     Byte                    ' r joystick - Y axis
psxJoyLX        VAR     Byte                    ' l joystick - X axis
psxJoyLY        VAR     Byte                    ' l joystick - Y axis

idx             VAR     Byte
xport           VAR     Byte


' -----[ EEPROM Data ]-----------------------------------------------------


' -----[ Initialization ]--------------------------------------------------

Reset:
  DEBUG CLS
  PAUSE 100


' -----[ Program Code ]----------------------------------------------------

Main:
  DEBUG HOME

  SEROUT Sio, Baud, ["!PSX", "V"]               ' get helper version
  SERIN  Sio, Baud, [STR id\3]
  DEBUG  "PSX Helper Version = ", STR id\3, CR

  SEROUT Sio, Baud, ["!PSX", "T"]               ' get helper type (mode)
  SERIN  Sio, Baud, [type]
  DEBUG  "PSX Helper Type = ", IHEX2 type, CR, CR

  SEROUT Sio, Baud, ["!PSX", "S"]               ' get PSX status
  SERIN  Sio, Baud, [STR psx\6]

  DEBUG "Btns", TAB, BIN8 psxThumb2, BIN8 psxThumb1, CR,
        "JoyRX", TAB, DEC psxJoyRX, CLREOL, CR,
        "JoyRY", TAB, DEC psxJoyRY, CLREOL, CR,
        "JoyLX", TAB, DEC psxJoyLX, CLREOL, CR,
        "JoyLY", TAB, DEC psxJoyLY, CLREOL, CR

  GOTO Main


' -----[ Subroutines ]----------------------------------------------------- 