fl

5 fwrite sd_dump1


\ Display Block(512bytes) inside SD-card
\ sd_dump filename
: sd_dump
\ Get blocknumber from filename   
\ if not filename, " FILE NOT FOUND"
_sd_fsp dup                                  \ Get cstr                           
if
     sd_find                                 \ Get block number
     dup
     \ Get header(1 Block) from SD-card to sd_cogbuf(Cog memory)
     sd_blockread
     \ Get number blocks allocated to this file
     sd_cogbuf h2B + COG@      
     dup cr ." Using Block Size:" . cr                       
     0 do
          dup
          ." Block number:" dup decimal . hex cr
          \ Read 1 block
          sd_blockread                     
          tbuf sd_cogbuf
          d32 0 do
               i d16 u* .word _ecs 
               2dup          
               \ Copy 8Long(32bytes) from Cog memory to tbuf
               4 cog>mem     
               tbuf d16 bounds
               do
                    i C@ .byte space
               loop     
               \ Display ASCII
               space 
               tbuf d16 bounds
               do
                    i C@ dup bl h7E between invert if drop h2E then emit
               loop
               cr
               \ next Cog memory
               4 +                
          loop     
          cr
          2drop
          \ Check if loop finished
          lasti? 0=
          if
               \ Stop if ESC key,  Display next block if space key
               ." Push ESC-key if stopping, space key if continue to display" cr
               begin               
                    fkey? and fkey? and or dup 
                    h1B =                         \ ESC key? 
                    if 
                         drop 
                         \ Break do-loop      Set lasti to current loop counter
                         0 RS@ seti
                         1    
                    else 
                         h20 =                    \ space key? 
                         if 1 else 0 then                         
                    then
               until
               \ Increment block number
               1+
          then
     loop  
     drop        
else
     drop _fnf
then
decimal
;

...